#!ipxe

# MoomsLab PXE — multi-version Debian menu
# proxydhcp/next-server = LXC pxe-srv vu depuis le subnet du client
set pxe-host ${proxydhcp/next-server}
isset ${pxe-host} || set pxe-host ${next-server}

:menu
menu MoomsLab PXE — Debian installer (next-server: ${pxe-host})
item --gap -- ----------- Linux installers -----------
item deb12   Debian 12 (bookworm)  - LTS / stable
item deb13   Debian 13 (trixie)    - current stable
item --gap -- ----------- Tools -----------
item shell   iPXE shell
item exit    Boot from disk
choose --default exit --timeout 30000 target || goto exit
goto ${target}

:deb12
set release-num 12
goto install

:deb13
set release-num 13
goto install

:install
echo Booting Debian ${release-num} installer (preseed) from ${pxe-host}...
kernel http://${pxe-host}/debian-${release-num}/linux auto=true priority=critical url=http://${pxe-host}/preseed/debian${release-num}.cfg interface=auto netcfg/dhcp_timeout=60
initrd http://${pxe-host}/debian-${release-num}/initrd.gz
initrd http://${pxe-host}/debian-${release-num}/firmware.cpio.gz
boot

:shell
echo Type "exit" to return to menu.
shell
goto menu

:exit
echo Booting from local disk...
exit